【Unity3D】Shader常量、变量、结构体、函数

1 源码路径

Unity Shader 常量、变量、结构体、函数一般可以在 Unity Editor 安装目录下面的【Editor\Data\CGIncludes\UnityShader】目录下查看源码，主要源码文件如下：

• UnityCG.cginc
• UnityShaderUtilities.cginc
• UnityShaderVariables.cginc

2 Shader 常量

#define UNITY_PI            3.14159265359f
#define UNITY_TWO_PI        6.28318530718f
#define UNITY_FOUR_PI       12.56637061436f
#define UNITY_INV_PI        0.31830988618f
#define UNITY_INV_TWO_PI    0.15915494309f
#define UNITY_INV_FOUR_PI   0.07957747155f
#define UNITY_HALF_PI       1.57079632679f
#define UNITY_INV_HALF_PI   0.636619772367f

3 Shader 变量

1）时间变量

// Time (t = time since current level load) values from Unity
float4 _Time; // (t/20, t, t*2, t*3)
float4 _SinTime; // sin(t/8), sin(t/4), sin(t/2), sin(t)
float4 _CosTime; // cos(t/8), cos(t/4), cos(t/2), cos(t)
float4 unity_DeltaTime; // dt, 1/dt, smoothdt, 1/smoothdt

2）相机和光源的世界坐标

float3 _WorldSpaceCameraPos; // 相机的世界坐标
half4 _WorldSpaceLightPos0; // 光源的世界坐标(当光源是平行光时, _WorldSpaceLightPos0表示灯光照射方向)

3）投影参数

// x = 1 or -1 (-1 if projection is flipped)
// y = near plane
// z = far plane
// w = 1/far plane
float4 _ProjectionParams;

4）屏幕参数

// x = width
// y = height
// z = 1 + 1.0/width
// w = 1 + 1.0/height
float4 _ScreenParams;

5）MVP 矩阵

float4x4 UNITY_MATRIX_M, unity_ObjectToWorld; // [模型空间->世界空间]的变换矩阵M
float4x4 UNITY_MATRIX_V, unity_MatrixV; // [世界空间->观察空间]的变换矩阵V
float4x4 UNITY_MATRIX_P, glstate_matrix_projection; // [观察空间->裁剪空间]的变换矩阵P
float4x4 UNITY_MATRIX_MV, unity_MatrixMV; // [模型空间->观察空间]的变换矩阵MV
float4x4 UNITY_MATRIX_VP, unity_MatrixVP; // [世界空间->裁剪空间]的变换矩阵VP
float4x4 UNITY_MATRIX_MVP, unity_MatrixMVP; // [模型空间->裁剪空间]的变换矩阵MVP
float4x4 UNITY_MATRIX_I_V, unity_MatrixInvV; // V矩阵的逆矩阵
float4x4 UNITY_MATRIX_T_MV, unity_MatrixTMV; // MV矩阵的转置
float4x4 UNITY_MATRIX_IT_MV, unity_MatrixITMV; // MV矩阵的逆转矩阵
float4x4 unity_WorldToObject; // [世界空间->模型空间]的变换矩阵M

说明：unity_ObjectToWorld 与 unity_WorldToObject 互为逆矩阵。

4 Shader 结构体

1）appdata_base

struct appdata_base {
    float4 vertex : POSITION; // 模型坐标系下顶点坐标
    float3 normal : NORMAL; // 模型坐标系下法线向量
    float4 texcoord : TEXCOORD0; // 纹理坐标
    UNITY_VERTEX_INPUT_INSTANCE_ID
};

2）appdata_tan

struct appdata_tan {
    float4 vertex : POSITION; // 模型坐标系下顶点坐标
    float4 tangent : TANGENT; // 模型坐标系下切线向量
    float3 normal : NORMAL; // 模型坐标系下法线向量
    float4 texcoord : TEXCOORD0; // 纹理坐标
    UNITY_VERTEX_INPUT_INSTANCE_ID
};

3）appdata_full

struct appdata_full {
    float4 vertex : POSITION; // 模型坐标系下顶点坐标
    float4 tangent : TANGENT; // 模型坐标系下切线向量
    float3 normal : NORMAL; // 模型坐标系下法线向量
    float4 texcoord : TEXCOORD0; // 纹理坐标0
    float4 texcoord1 : TEXCOORD1; // 纹理坐标1
    float4 texcoord2 : TEXCOORD2; // 纹理坐标2
    float4 texcoord3 : TEXCOORD3; // 纹理坐标3
    fixed4 color : COLOR; // 顶点颜色
    UNITY_VERTEX_INPUT_INSTANCE_ID
};

4）appdata_img

struct appdata_img
{
    float4 vertex : POSITION; // 模型坐标系下顶点坐标
    half2 texcoord : TEXCOORD0; // 纹理坐标
    UNITY_VERTEX_INPUT_INSTANCE_ID
};

5）v2f_img

struct v2f_img
{
    // 作为顶点着色器输出时, pos指裁剪坐标系下的坐标; 作为片元着色器输入时, pos指屏幕坐标系下的坐标
    float4 pos : SV_POSITION;
    half2 uv : TEXCOORD0; // 纹理坐标
    UNITY_VERTEX_INPUT_INSTANCE_ID
    UNITY_VERTEX_OUTPUT_STEREO
};

说明：作为顶点着色器输出时, pos指裁剪坐标系下的坐标; 作为片元着色器输入时, pos指屏幕坐标系下的坐标。

6）vert_img 着色器

v2f_img vert_img(appdata_img v)
{
    v2f_img o;
    UNITY_INITIALIZE_OUTPUT(v2f_img, o);
    UNITY_SETUP_INSTANCE_ID(v);
    UNITY_INITIALIZE_VERTEX_OUTPUT_STEREO(o);
    o.pos = UnityObjectToClipPos(v.vertex);
    o.uv = v.texcoord;
    return o;
}

用户可以通过以下方式引用内置顶点着色器：

#pragma vertex vert_img

5 Shader 函数

5.1 基础函数

1）数值计算

sign(x)、abs(x) // 符号、绝对值
min(a, b)、max(a, b) // 最值函数
ceil(x)、floor(x)、round(x) // 取整函数
frac(x) // 取小数部分
fmod(x, y) // 取余数
rap(x) // 倒数(1/x)
sqrt(x)、pow(x) // 幂函数
exp(x)、exp2(x) // 指数函数(e^x、2^x)
log(x)、log10(x)、log2(x) // 对数函数
degrees(x)、radians(x) // 角度转换函数
sin(x)、cos(x)、tan(x)、asin(x)、acos(x)、atan(x) // 三角函数
sinh(x)、cosh(x)、tanh(x) // 双曲线函数
saturate(x) // 将x约束在0和1之间, 超过边界就取边界值
clamp(x, min, max) // 将x约束在min和max之间, 超过边界就取边界值
smoothstep (min, max, x) // 平滑比例, 公式: k=saturate((x-min)/(max-min)), y=k*k*(3-2*k)
lerp(a, b, f) // 插值, 公式: y=a+f*(b-a), a、b可以是向量

2）向量计算

all(vec) // 如果vec中每个分量都是非零的则返回true, 否则返回false
any(vec) // 如果vec中存在一个分量是非零的则返回true, 否则返回false
distance(pos1, pos2) // 计算pos1与pos2之间的距离
length(vec) // 计算向量的模长
normalize(vec) // 计算向量的单位向量
dot(vec1, vec2) // 向量点乘
cross(vec1, vec2) // 向量叉乘
reflect(i, n) // 根据入射向量和法线向量, 计算反射向量(i和n不需要归一化)
refract(i, n, ratio); // 根据入射向量、法线向量、折射率比值, 计算折射向量(i和n需要归一化, ratio为入射介质折射率/折射介质折射率, 或sin(折射角)/sin(入射角))

3）矩阵计算

mul(M, N)、mul(M, v), mul(v, M) // M*N、M*v、M'*v
determinant(M) // 计算矩阵的行列式
transpose(M) // 矩阵转置

补充：CG 中矩阵类型变量初始化顺序是按照行优先的顺序进行的，访问矩阵中元素也是按照行优先的顺序进行的；float3、float4 类型变量，既可以当作一个矢量，也可以当作一个 1 x n 的行矩阵或 n x 1 的列矩阵。

// 定义一个矩阵, 第一行: 1.0, 2.0, 3.0; 第二行: 4.0, 5.0, 6.0; 第三行: 7.0, 8.0, 9.0
float3x3 M = float3x3(1.0, 2.0, 3.0, 4.0, 5.0, 6.0, 7.0, 8.0, 9.0);
// 得到矩阵M的第一行, 即: 1.0, 2.0, 3.0
float3 row = M[0];
// 得到矩阵M的第2行、第3列元素, 即: 6.0
float e = M[1][2];

4）纹理计算

tex2D(sampler2D, uv_Tex) // 查询纹理坐标对应的纹理值
UnpackNormal(color) // 根据法线纹理解析法线向量

5.2 坐标和向量变换

1）坐标变换

// 模型空间->观察空间
float3 UnityObjectToViewPos(float3 pos) // mul(UNITY_MATRIX_MV, float4(pos, 1.0)).xyz
float3 UnityObjectToViewPos(float4 pos) // UnityObjectToViewPos(pos.xyz)
// 模型空间->裁剪空间
float4 UnityObjectToClipPos(float3 pos) // mul(UNITY_MATRIX_MVP, float4(pos, 1.0))
float4 UnityObjectToClipPos(float4 pos) // UnityObjectToClipPos(pos.xyz)
// 世界空间->观察空间
float3 UnityWorldToViewPos(float3 pos) // mul(UNITY_MATRIX_V, float4(pos, 1.0)).xyz
// 世界空间->裁剪空间
float4 UnityWorldToClipPos(float3 pos) // mul(UNITY_MATRIX_VP, float4(pos, 1.0))
// 观察空间->裁剪空间
float4 UnityViewToClipPos(float3 pos) // mul(UNITY_MATRIX_P, float4(pos, 1.0))

2）向量变换

// 模型空间->世界空间
float3 UnityObjectToWorldDir(float3 dir) // normalize(mul((float3x3)unity_ObjectToWorld, dir))
// 世界空间->模型空间
float3 UnityWorldToObjectDir(float3 dir) // normalize(mul((float3x3)unity_WorldToObject, dir))

3）法线变换

// 模型空间->世界空间(已归一化)
float3 UnityObjectToWorldNormal(float3 norm) {
#ifdef UNITY_ASSUME_UNIFORM_SCALING // 统一缩放(x、y、z分量缩放系数一致)
    return UnityObjectToWorldDir(norm); // normalize(mul((float3x3)unity_ObjectToWorld, norm))
#else
    return normalize(mul(norm, (float3x3)unity_WorldToObject)); // mul(IT_M, norm) => mul(norm, I_M)
#endif
}

法线由切线计算而来，在模型空间中 A 点的切线向量为 v1，法线向量为 n1，经过模型变换（矩阵 M）后，切线向量为 v2，法线向量为 n2，假设法线向量的变换矩阵为 G，因此存在以下关系：

Unity 中线性变换主要有平移、旋转、缩放，由于向量不受平移变换影响，因此，对于法线向量而言，只受旋转和缩放影响。

• 当 M 只包含旋转变换时，M 是正交矩阵，M-1 = M'，因此 G = M；
• 当 M 只包含统一缩放变换时，M = k·E，因此 G = 1/k·E = 1/(k^2)·M，由于法线向量只需要方向，后面会进行归一化，因此可以简写 G = M；
• 当 M 只包含旋转变换和统一缩放变换时，G = 1/(k^2)·M，由于法线向量只需要方向，后面会进行归一化，因此可以简写 G = M；

4）其他变换

// 观察空间->裁剪空间
float2 TransformViewToProjection (float2 v) // mul((float2x2)UNITY_MATRIX_P, v)
float3 TransformViewToProjection (float3 v) // mul((float3x3)UNITY_MATRIX_P, v)

5.3 计算指向相机和光源的向量

1）计算顶点指向相机的向量

// _WorldSpaceCameraPos.xyz - worldPos
float3 ObjSpaceViewDir(float4 v) // 输入: 模型空间坐标, 输出: 模型空间坐标
float3 WorldSpaceViewDir(float4 localPos) // 输入: 模型空间坐标, 输出: 世界空间坐标
float3 UnityWorldSpaceViewDir(float3 worldPos) // 输入: 世界空间坐标, 输出: 世界空间坐标

2）计算顶点指向光源的向量

// mul(unity_WorldToObject, _WorldSpaceLightPos0).xyz - v.xyz
float3 ObjSpaceLightDir(float4 v) // 输入: 模型空间坐标, 输出: 模型空间坐标
float3 WorldSpaceLightDir(float4 localPos) // 输入: 模型空间坐标, 输出: 世界空间坐标
float3 UnityWorldSpaceLightDir(float3 worldPos) // 输入: 世界空间坐标, 输出: 世界空间坐标

声明：本文转自【Unity3D】Shader常量、变量、结构体、函数